/*
  automatischer Übersetzung-Script für FinalWriter
  (c) 1996 Denis Unger (16.07.1996)

  Dieser Script übersetzt den markierten Teil vom Dokument und schreibt
  die Übersetzung entweder ans Dokument-Ende oder an die Stelle, wo
  der markierte Text stand.
*/


/* Nun kommen persönliche Einstellungen, welche evtl. geändert werden müssen ...*/
/********************************************************************************/
FLM             = 'FLM:FLM'             /* Programm FLM */
FWfont1         = 'SoftSans'            /* Font für gefundene Wörter */
FWfont2         = 'SoftSans_Bold'       /* Font für nichtgefundene Wörter */
/********************************************************************************/

Options Results

gestartet = 0
if ~show('PORTS','FLM') then do          /* FLM schon gestartet ? */
    address command 'run >NIL: ' || FLM  /* starte FLM */
    address command "SYS:Rexxc/WaitForPort FLM"
    gestartet = 1        /* FLM wird nach Übersetzung beendet */
end

  ShowMessage 1 0 '"Welcher Bereich soll Übersetzt werden?" "" "" " Alles " " Markierter Bereich " ""'
  Bereich = RESULT

  ShowMessage 1 0 '"Übersetzungs-Art ?" "" "" "Automatisch" "Benutzer" ""'
  trans_art = RESULT

/* Im Moment feste Sprache Englisch und Deutsch*/
  ShowMessage 1 0 '"Übersetzungsrichtung ?" "" "" "  Deutsch->Englisch   " "Englisch->Deutsch" ""'        /* in welche Richtung soll übersetzt werden */
    Richtung = RESULT
  if Richtung = '2' then do
    address FLM SETLANGUAGE englisch
  end
  else do
    address FLM SETLANGUAGE deutsch
  end

  ShowMessage 1 0 '"Wohin soll die Übersetzung geschrieben werden?" "" "" " An das Dokument-Ende " " Orginal überschreiben " ""'
  Ziel = RESULT

  if Bereich = '1' then SelectAll  /* Alles markieren, da "Alles Übersetzen" gewählt */

  Extract

  text = RESULT /* Markierter Text */

  ShowMessage 1 0 '"Soll der markierte Text nun übersetzt werden !" "" "" "Ja" "Nein" ""'
  if RESULT = 2 then exit

  if Ziel = 1 then do
    /* Cursor ans Dokument-Ende */
    AltDown
    CtrlDown
    Cursor 'Down'
    CtrlUp
    AltDown
  end

do i=1 to words(text)

  wort = word(text,i) /* 1., 2., 3., ... Wort */
  address FLM lookword wort
  address FLM found    /* wurde Wort gefunden*/
  gefunden = RESULT

  if trans_art = 2 then do
    /* Benutzer steuert Übersetzung */
    ShowMessage 1 0 '"Übersetzung auswählen !" "" "" "Übersetzung" "Original" "Abbruch"'
    nutzer = RESULT
    if nutzer = 3 then exit
    if nutzer = 2 then do
      Type wort
    end
    if nutzer = 1 then do
      address FLM takeword
      Type RESULT
    end
  end
  else do
    /* Automatische Übersetzung */
    if gefunden = 0 then do
      address FLM takeword
      taked_word = RESULT
      Font FWFont1
      Type taked_word
    end
    else do
      Font FWfont2
      Type wort
    end
  end
  Type ' ' /* Leerzeichen zwischen den Wörtern */

end

ShowMessage 1 0 '"Textübersetzung beendet." "" "" "OK" "" ""'

if gestartet = 1 then do
 /* wurde FLM durch das Script gestartet, so wird es nun auch wieder beendet */
 address FLM QUIT
end

exit