/* CED-FLM.ced uebersetzt das Wort, auf dem der CED-Cursor steht.

   (c) Markus Krajewski (a2647290@smail.rrz.Uni-Koeln.DE), 13.10.94, Ver.1.0

   Dieses Script laesst das Wort unter dem CED-Cursor von dem im Hintergrund
   laufenden FLM uebersetzen.


*****************************************************
Achtung! Individuell anpassen: Programmpfad von FLM:
*****************************************************
*/

path="PRG:FLM/"

/* ++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++=
 */

LF='0A'X
initiation="run >nil: "||path||"FLM"

/* FLM wird geladen. */

IF ~show('P','FLM') THEN DO
 ADDRESS COMMAND initiation
END


/* CED greift sich die zu uebersetzende Vokabel. */

OPTIONS RESULTS

ADDRESS 'rexx_ced'

GetWord
word=RESULT

string = "Soll die Vokabel "||word||" uebersetzt werden? ..."
OKAY2 string
IF RESULT=0 THEN EXIT

/* FLM blaettert, ... */

ADDRESS 'FLM'
LOOKWORD word

TAKEWORD

/* ... findet etwas ... */

IF Symbol('RESULT')='LIT' THEN EXIT

/*  und ruft es dem CED zu.*/

ADDRESS 'rexx_ced'

alternative=RESULT

translation=word||' ist uebersetzt mit: '||alternative||'.'||LF||'Andere Uebersetzung aus Liste wählen'||LF||'und anschließend CANCEL'||LF||'oder direkt weiter mit OK.'

OKAY2 translation
IF RESULT=0 THEN DO
 call NimmWort
END

string ="Mit OK wird das urspruengliche Wort" || LF || "durch die Uebersetzung ausgetauscht."

OKAY2 string
IF RESULT=0 THEN EXIT

alternative=alternative||' '

'Prev word'
'Delete word'
TEXT alternative

/* Das FLM-Fenster verschwindet */

ADDRESS 'FLM'
QUIT


EXIT


/* Subroutine für alternative Vokabeln */

NimmWort:

ADDRESS 'FLM'
TAKEWORD

IF Symbol('RESULT')='LIT' THEN EXIT

ADDRESS 'rexx_ced'
alternative=RESULT

translation=word||' ist uebersetzt mit: '||alternative

OKAY2 translation
IF RESULT=0 THEN DO
 call NimmWort
 Wait for 3
END

RETURN